$!===============================================================================================
$! EXTRACT_RESULTS.COM
$! by Helen Buie and Sarah Manske
$! March 18, 2009
$!
$! Extracts results with uct_list and creates a list of files analyzed.
$! Based on UU:UCT_EVALUATION_3DRESULT_APPEND.COM
$!===============================================================================================
$
$  FNAME == F$PARSE("''ORG_FILE'",,,"NAME")
$
$!---------------------------------------------------------------
$! Search AIM header for measurement number, store in MEAS_NO
$!---------------------------------------------------------------
$  PIPE AIX 'AIM_FILE' | SEARCH SYS$PIPE "Index Measurement"| -
        (READ SYS$INPUT LINE ; DEFINE/JOB LINE_LOG &LINE)
$      LINE_SYM == F$TRNLNM("LINE_LOG")
$      LINE_SYM == F$EDIT(LINE_SYM,"TRIM,COMPRESS")
$  MEAS_NO == F$EXTRACT(18,4,LINE_SYM)
$
$
$!---------------------------------------------------------------
$! Write a temporary file to run uct_list and append results
$!---------------------------------------------------------------
$
$  TEMP_FILE    	:==  SYS$SCRATCH:'FILENAME'.COM
$  D3RESULT	:==  'DEV''RESULT_DIR''RESULT_FILE'_TEMP.TXT
$  D3RESULT_ALL	:==  'DEV''RESULT_DIR''RESULT_FILE'.TXT
$
$  OPEN/WRITE OUTFILE 'TEMP_FILE'
$  WRITE OUTFILE "$! Reading out 3D result database and putting it into appended .txt file"
$  WRITE OUTFILE "$!"
$  WRITE OUTFILE "$ IF F$SEARCH(""''D3RESULT_ALL'"") .EQS. """" "
$  WRITE OUTFILE "$ THEN"
$  WRITE OUTFILE "$   COPY UU:UCT_3D_LIST_HEADER_W_CTH.TXT ''D3RESULT_ALL'"
$  WRITE OUTFILE "$ ENDIF"    
$
$  WRITE OUTFILE "$ UCT_LIST"
$  WRITE OUTFILE "UU:UCT_3D_LIST_NOHEAD_W_CTH.TXT"
$  WRITE OUTFILE "''D3RESULT'"
$  WRITE OUTFILE "0" ! DEFAULT UNIT
$  WRITE OUTFILE "''MEAS_NO'"
$  WRITE OUTFILE "''MEAS_NO'"
$
$  WRITE OUTFILE "$ APPEND ''D3RESULT' ''D3RESULT_ALL'"
$
$  WRITE OUTFILE "$ DELETE ''D3RESULT';"
$  CLOSE OUTFILE
$
$!---------------------------------------------------------------
$! Run temp file then delete it
$!---------------------------------------------------------------
$
$  @'TEMP_FILE'
$  DEL 'TEMP_FILE';
$
$!---------------------------------------------------------------
$! Create a list of filenames to go with the results
$!---------------------------------------------------------------
$
$  FILELIST    	:==  'DEV''RESULT_DIR''RESULT_LIST'.TXT
$
$  IF F$SEARCH("''FILELIST'") .EQS. "" 
$  THEN
$     OPEN/WRITE OUTFILE 'FILELIST' 
$     WRITE OUTFILE "''FNAME'"     
$  ELSE
$     OPEN/APPEND OUTFILE 'FILELIST'  
$     WRITE OUTFILE "''FNAME'"
$  ENDIF
$  CLOSE OUTFILE