$!============================================================================================
$!  AUTOCONTOUR EVALV6 FROM COMMAND LINE
$!  H. Buie, UofC 2009
$!
$!  This script is used to call the Buie-Burghart-Scanco autocontour
$!  script from the UE directory.
$!
$!  Modified by Kyle Nishiyama  Feb. 16, 2010
$!  -To use for C179 data and for use with seg file instead of orig aim
$!
$!  Usage:
$!  $ @COM:HIJACK_AUTOCONTOUR.COM DISK3:[MICROCT.PROJECTS.C179.MODELS]XXXXXXXX.AIM 
$!  $ SCANCO_SUBMIT_COMMAND COM:HIJACK_AUTOCONTOUR.COM  -
$!      /PARA=(DISK3:[MICROCT.PROJECTS.C179.MODELS]XXXXXXXX.AIM)
$!============================================================================================
$
$ LD = "DISK3:[MICROCT.PROJECTS.C179.LOG]"   
$ SHOW SYMBOL P%
$ IF P1 .NES. "" THEN CALL DO_IT "''P1'" 
$!
$ EXIT
$!
$ DO_IT: SUBROUTINE
$
$   ORGAIM = P1
$
$!  Search using AIX in seg filename instead of grayscale aim KN
$
$   INITIAL_FILENAME = F$PARSE("''P1'",,,"NAME")
$   INITIAL_DEV =   F$PARSE("''P1'",,,"DEVICE") 
$   INITIAL_DIR =   F$PARSE("''P1'",,,"DIRECTORY")
$
$   INITIAL_SEG :=  'INITIAL_DEV''INITIAL_DIR''INITIAL_FILENAME'_SEG.AIM
$
$   AIX == "$UT:D3_IO_EXAMINE -L"
$
$   PIPE AIX 'INITIAL_SEG' | SEARCH SYS$PIPE "Index Patient"| -
        (READ SYS$INPUT LINE ; DEFINE/JOB LINE_LOG &LINE)
$      LINE_SYM = F$TRNLNM("LINE_LOG")
$      LINE_SYM = F$EDIT(LINE_SYM,"TRIM,COMPRESS")
$   SAMPLE_NO = F$EXTRACT(14,4,LINE_SYM)
$
$   PIPE AIX 'INITIAL_SEG' | SEARCH SYS$PIPE "Index Measurement"| -
        (READ SYS$INPUT LINE ; DEFINE/JOB LINE_LOG &LINE)
$      LINE_SYM = F$TRNLNM("LINE_LOG")
$      LINE_SYM = F$EDIT(LINE_SYM,"TRIM,COMPRESS")
$   MEAS_NO = F$EXTRACT(18,4,LINE_SYM)
$
$   SHOW SYM SAMPLE_NO
$   SHOW SYM MEAS_NO
$
$   FILENAME = F$PARSE("''ORGAIM'",,,"NAME")
$   DEV =   F$PARSE("''ORGAIM'",,,"DEVICE") 
$   DIR =   F$PARSE("''ORGAIM'",,,"DIRECTORY")   
$   LOC =  DEV + DIR
$   SHOW SYM LOC 
$!  Shortened version of filename to avoid syntax errors for .com and .log files KN  
$   FILENAME_SHORT = F$EXTRACT(4,6, FILENAME)
$   IF ORGAIM .NES. ""
$   THEN
$     ORGAIM = ORGAIM - F$PARSE(ORGAIM,,,"VERSION") 
$     PAR1 = "EVAL:UE:UCT_EVALUATION_V6.COM|UE:IPLV6_UPAT_AUTOCONTOUR.COM"
$     PAR2 = "FILE:''LOC'|''FILENAME'|+.ISQ|+.AIM|+_SEG.AIM|+.GOBJ|+_CRTX.GOBJ|+_TRAB.GOBJ|+_AUTO2.GOBJ|+_CRTXFILL.AIM|+_CRTXSEG.AIM|+_CRTXPO.AIM|+_CRTXPO.GOBJ"
$     PAR3 = "JOB:AUTO_''FILENAME'|XXXX|''SAMPLE_NO'|''MEAS_NO'|4|''LD'|+.LOG|SYS$FAST"
$     PAR4 = "MISC1:5|15|2|5|5|1"
$     @UE:UCT_EVALUATION_V6 "''PAR1'" "''PAR2'" "''PAR3'" "''PAR4'"   
$   ELSE
$     WRITE SYS$OUTPUT "FILE NOT FOUND ''ORGAIM'"
$   ENDIF
$   EXIT
$ ENDSUBROUTINE
$
$
$ EXIT